// sewers worker

BEGIN AC#FPSEW

CHAIN IF ~Global("AC#LoreQuestMain","GLOBAL",2)~ THEN AC#FPSEW SEWERWOR.00
@0
END
IF~~THEN REPLY @1 EXTERN AC#FPSEW SEWERWOR.01
IF~~THEN REPLY @2 EXTERN AC#FPSEW bye_leave

CHAIN AC#FPSEW SEWERWOR.01
@3
==AC#FPSEW @4
END
IF~~THEN REPLY @5 EXTERN AC#FPSEW SEWERWOR.02
IF~~THEN REPLY @6 EXTERN AC#FPSEW SEWERWOR.03

CHAIN AC#FPSEW SEWERWOR.02
@7
END
IF~~THEN REPLY @8 EXTERN AC#FPSEW SEWERWOR.03

CHAIN AC#FPSEW SEWERWOR.03
@9
END
IF~~THEN REPLY @10 EXTERN AC#FPSEW seen_loremaster_high
IF~~THEN REPLY @11 EXTERN AC#FPSEW sewerworker_bye

	CHAIN AC#FPSEW seen_loremaster_high
	@12
	END
	IF~~THEN REPLY @11 EXTERN AC#FPSEW sewerworker_bye

CHAIN AC#FPSEW sewerworker_bye
@13
DO ~SetGlobal("AC#LoreQuestMain","GLOBAL",3)
EraseJournalEntry(@100001)
AddJournalEntry(@100002,QUEST)
EscapeArea()~ EXIT

CHAIN AC#FPSEW bye_leave
@14
EXIT

CHAIN IF ~True()~ THEN AC#FPSEW hello_stinky
@84
EXIT


//strange woman
BEGIN AC#FPLAD

CHAIN IF ~StateCheck(Myself,STATE_CHARMED)
AreaCheck("AC#FP1")~ THEN AC#FPLAD hello_charmed
@85
DO ~SetGlobal("AC#EtateCharmed","AC#FP1",1)~ EXIT
//1st

CHAIN IF ~Global("AC#LoreQuestMain","GLOBAL",5)~ THEN AC#FPLAD 01.00
@15
END
IF~~THEN REPLY @16 EXTERN AC#FPLAD 01.01
IF~~THEN REPLY @17 EXTERN AC#FPLAD you_are_the_one
IF~~THEN REPLY @18 EXTERN AC#FPLAD bye_01

	CHAIN AC#FPLAD bye_01
	@19
	EXIT
	
	CHAIN AC#FPLAD you_are_the_one
	@20
	END
	IF~~THEN REPLY @21 EXTERN AC#FPLAD 01.01
	IF~~THEN REPLY @22 EXTERN AC#FPLAD bye_01

CHAIN AC#FPLAD 01.01
@23
END
IF~~THEN REPLY @24 EXTERN AC#FPLAD 01.02
IF~~THEN REPLY @25 EXTERN AC#FPLAD 01.02

CHAIN AC#FPLAD 01.02
@26
END
IF~~THEN REPLY @27 EXTERN AC#FPLAD 01.03
IF~~THEN REPLY @28 EXTERN AC#FPLAD 01.03
IF~~THEN REPLY @29 EXTERN AC#FPLAD 01.03

CHAIN AC#FPLAD 01.03
@30
= @31
END
IF~~THEN REPLY @32 EXTERN AC#FPLAD wait_i_try_to_save_books_too
IF~~THEN REPLY @33 EXTERN AC#FPLAD try_to_save_books_too
IF~~THEN REPLY @34 EXTERN AC#FPLAD try_to_save_books_too

	CHAIN AC#FPLAD wait_i_try_to_save_books_too
	@35
	EXTERN AC#FPLAD try_to_save_books_too

CHAIN AC#FPLAD try_to_save_books_too
@36
= @37
= @38
END
IF~~THEN REPLY @39 EXTERN AC#FPLAD 01.04
IF~~THEN REPLY @40 EXTERN AC#FPLAD 01.05
IF~~THEN REPLY @41 EXTERN AC#FPLAD 01.07

CHAIN AC#FPLAD 01.04
@42
EXTERN AC#FPLAD 01.08

CHAIN AC#FPLAD 01.05
@43
EXTERN AC#FPLAD 01.08

CHAIN AC#FPLAD 01.07
@44
EXTERN AC#FPLAD 01.08

CHAIN AC#FPLAD 01.08
@45 
= @46 
== JAHEIJ IF ~InParty("JAHEIRA") !StateCheck("JAHEIRA",CD_STATE_NOTVALID)~ THEN @47
== AC#FPLAD @48
== VICONJ IF ~InParty("VICONIA") !StateCheck("VICONIA",CD_STATE_NOTVALID)~ THEN @49
== AC#FPLAD @50
END
IF~~THEN REPLY @51 EXTERN AC#FPLAD 01.09
IF~~THEN REPLY @52 EXTERN AC#FPLAD 01.09
IF~~THEN REPLY @53 EXTERN AC#FPLAD sceptic_unveilers
IF~~THEN REPLY @54 EXTERN AC#FPLAD sceptic_unveilers
//IF~~THEN REPLY @55 EXTERN AC#FPLAD 01.10

	CHAIN AC#FPLAD sceptic_unveilers
	@56 
	END
	IF~~THEN REPLY @57 EXTERN AC#FPLAD 01.09
	IF~~THEN REPLY @52 EXTERN AC#FPLAD 01.09
	//IF~~THEN REPLY @55 EXTERN AC#FPLAD 01.10

CHAIN AC#FPLAD 01.09
@58
END
IF~~THEN REPLY @59 EXTERN AC#FPLAD 01.11
IF~~THEN REPLY @60 EXTERN AC#FPLAD 01.11
//IF~~THEN REPLY @61 EXTERN AC#FPLAD 01.10

CHAIN AC#FPLAD 01.11
@62
END
IF ~~ THEN REPLY @63 EXTERN AC#FPLAD 01.12
IF ~~ THEN REPLY @64 EXTERN AC#FPLAD 01.12
IF ~~ THEN REPLY @65 EXTERN AC#FPLAD 01.12
IF ~~ THEN REPLY @66 EXTERN AC#FPLAD 01.12

CHAIN AC#FPLAD 01.12
@67 
= @68
EXTERN AC#FPLAD find_me_sewers

CHAIN AC#FPLAD find_me_sewers
@69
EXTERN AC#FPLAD bye_tunnels

CHAIN AC#FPLAD bye_tunnels
@70
DO ~SetGlobal("AC#LoreQuestMain","GLOBAL",7)
EraseJournalEntry(@100004)
AddJournalEntry(@100005,QUEST)
EscapeArea()~ EXIT

CHAIN AC#FPLAD 01.10
@71
DO ~SetGlobal("AC#LoreQuestMain","GLOBAL",8) Enemy()~ EXIT

//2nd

CHAIN IF ~Global("AC#LoreQuestMain","GLOBAL",7) AreaCheck("AC#FP1")~ THEN AC#FPLAD 02.00
@72
==AC#FPLAD @73
END
IF~~THEN REPLY @74 EXTERN AC#FPLAD controlled_02
IF~~THEN REPLY @75 EXTERN AC#FPLAD controlled_02
IF~~THEN REPLY @76 EXTERN AC#FPLAD controlled_02
IF~~THEN REPLY @77 EXTERN AC#FPLAD controlled_02
IF~~THEN REPLY @78 EXTERN AC#FPLAD controlled_fight

	CHAIN AC#FPLAD controlled_02
	@79
	EXTERN AC#FPLAD controlled_03
		
		CHAIN AC#FPLAD controlled_03
		@80
		EXTERN AC#FPLAD controlled_04
		
		CHAIN AC#FPLAD controlled_04
		@81
		EXTERN AC#FPLAD controlled_fight

CHAIN AC#FPLAD controlled_fight
@82
==AC#FPLAD @83
DO ~SetGlobal("AC#LoreQuestMain","GLOBAL",8) SetGlobal("AC#LoreQuestAmbush","GLOBAL",1) 
EraseJournalEntry(@100005)
AddJournalEntry(@100006,QUEST) Enemy()~ EXIT